Función SI de Excel

Función SI de Excel

ANUNCIOS

Dibujo de las fórmula SI de Excel

Uso:

La función SI de Excel comprueba si se cumple una prueba lógica que le especificamos. Devuelve un valor si esa prueba es verdadera y otro si es falsa.

Sintaxis:

Para llamar a la fórmula SI utilizamos el siguiente comando:

=SI (prueba_lógica; valor_si_verdadero; valor_si_falso)

Donde:

  • prueba_lógica: Obligatoria. Puede ser desde una fórmula lógica matemática, como B1>2 o A3=0, una comparación con un texto o una cadena alfanumérica, como C3<>»SI» o bién D5=»CONSTITUCION» hasta una fórmula de cadenas de Excel. Si se cumple la prueba lógica, se considera verdadera y la función asigna el valor_si_verdadero. En caso de que sea falsa se asigna el valor_si_falso.
  • valor_si_verdadero: Opcional. Es el valor que asignará la función SI en el caso de que la prueba lógica sea verdadera. Puede ser un valor numérico como 7, una cadena como «Verdadero» o incluso otra fórmula de Excel. En el caso de omitir esta variable, dejando la función como =SI(B2<5;;"Falso"), su valor será 0 por defecto.
  • valor_si_falso: Opcional. Se le asignará este valor a la función si de Excel la prueba_lógica da falso. Al igual que el valor_si_verdadero, puede tomar cualquier tipo de valor o fórmula. Si se omite este valor en la sintaxis, como por ejemplo =SI(B2=»Ramón»;3;), se le asignará por defecto el valor 0.

Importante: en la casilla prueba_lógica, si el valor a comparar es numérico, se escribe ese valor sin más B2=5, pero si es un texto o una cadena alfanumérica, obligatoriamente debe estar encerrada entre comillas H2=»PASA» o en alfanumerico A6=»AUDI3″.

Las comparaciones son = equivale a igual que, > mayor que, < menor que, >= mayor o igual que, <= menor o igual que y <> diferente a.

La función SI de Excel se puede utilizar desde la celda destino escribiendo sintaxis precedida de un signo de igualdad =SI(C2-B2>10;0;1) o desde el botón de funciones de Excel. Si optamos por pulsar el botón, debemos buscar en el buscador de funciones la fórmula SI o desplegar la categoría de las funciones lógicas. Los comandos son los siguientes:

Comandos de la función SI de Excel. Argumentos de la función.

Ejemplo 1:

ANUNCIOS



Supongamos que tenemos una partida de plátanos, de manera que si no miden igual o más que 15 cm de longitud no los podemos vender en el mercado. Catalogaremos como «Apto» el plátano que podemos vender (mide igual o más de 15 cm) y como «No apto» el pequeño.

Diagrama del ejemplo 1 de la fórmula SI de Excel
Ejemplo 1 de la fórmula SI de Excel

Utilizamos la función lógica de la desigualdad para identificar los plátanos aptos de los no aptos. Cuando miden 15 o más centímetros, la prueba lógica es verdadera y por lo tanto toma el valor_si_verdadero, es decir, «Apto». En caso contrario es «No apto». La fórmula SI utilizada es:

=SI (B2>=15; «Apto»; «No apto»)

Ejemplo 2:

Ahora pondremos otro ejemplo con una función de texto. Supongamos que tenemos un listado de los nombres de los trabajadores de una empresa. Queremos determinar si el nombre de cada trabajador es «Largo» o «Corto». Supongamos que consideramos que un nombre es largo si tiene más de siete letras.

Ejemplo 2 de la fórmula SI de Excel

Para este caso utilizamos la función de texto LARGO. Esta función se aplica sobre una cadena y determina el número de caracteres que tiene un campo. Por ejemplo, LARGO(«Ramón»)=5 porque tiene 5 carácteres. Por tanto, determinamos el número de caracteres que tiene cada nombre y con la prueba lógica valoramos si su nombre es largo o corto. La fórmula utilizada es:

=SI (LARGO(A2)>7; «Largo»; «Corto»)

Ejemplo 3:

En este ejemplo, realizaremos una función en la que el valor_si_verdadero y valor_si_falso pueden ser también fórmulas del excel. Tenemos un listado de alumnos universitarios, de manera que no todos asistieron a clase. Marcamos la asistencia a clase en «Si» o «No». Todos los alumnos realizaron el examen y el trabajo final. La nota de trabajo final podría subir hasta un punto, con la condición de que se asiste a clase. En caso contrario, la nota sería la obtenida en el examen final.

Diagrama del ejemplo 3 de la fórmula SI de Excel
Ejemplo 3 de la fórmula SI de Excel

En esta caso, si se cumple la prueba_lógica (el alumno ha ido a clase) el valor_si_verdadero es la fórmula Excel SUMA, la cual suma la nota del examen y la del trabajo. La fórmula del SI utilizada es:

=SI (B2=»Si»; SUMA(C2,D2); C2)

Ejemplo 4:

Los vendedores de una empresa tienen en su sueldo una parte fija y otra variable, que es un incentivo a comisión, según las ventas realizadas. El incentivo es un porcentaje creciente sobre las ventas. Si vende más de 20.000 €, tiene un incentivo del 8% sobre la cantidad vendida, si la venta está entre 20.000 € y más de 15.000 €, le añaden un 6%, si vende entre 15.000 € y más de 9.000 €, el suplemento es el 4%. Finalmente, si las ventas son de 9.000 € o una cantidad inferior, el incentivo se limitarà a un 1% sobre la cantidad vendida.

La fórmula consta de una série de funciones SI que están anidadas en una de las alternativas de la función SI de Excel anterior, ocupando el lugar de la alternativa “falso” de la prueba lógica.

Obsérvese que, para añadir a la parte variable del sueldo los 600 € fijos, sumamos la casilla D2. Para fijar el valor de esta celda, que está en la columna D y en la fila 2, usamos la sintaxis $D$2.

Diagrama 1 del ejemplo 4 de la fórmula SI de Excel

Fijémonos en la celda D2.

Cuadro 1 del ejemplo 4 de la fórmula SI de Excel

=SI(B2>20000; B2*8%+$D$2; SI(B2>15000; B2*6%+$D$2; SI(B2>9000; B2*4%+$D$2; B2*1%+$D$2)))

La fórmula la hemos resuelto yendo de más a menos en el orden de las condiciones para los incentivos. Pero, veamos cómo obtendríamos igual resultado si ordenásemos las condiciones en sentido ascendente:

Diagrama 2 del ejemplo 4 de la fórmula SI de Excel
Cuadro 2 del ejemplo 4 de la fórmula SI de Excel

=SI(B2<=9000; B2*1%+$D$2; SI(B2<=15000; B2*4%+$D$2; SI(B2<=20000; B2*6%+$D$2; B2*8%+$D$2)))

Ejemplo 5:

Este ejercicio, incluye unas condiciones más complejas que requerirán introducir la función Y y la función O.

Un departamento de Recursos Humanos está buscando cubrir un puesto para un profesional en un puesto cualificado. Después de una primera fase, van a seleccionar a los candidatos finales, a los que se les exige que hayan cursado un máster MBA, que tengan 5 o más años de experiencia en el puesto y que su nivel de inglés sea alto. Pero exigen también o una licenciatura universitaria en Informática o bien la licenciatura en Estadística.

Diagrama del ejemplo 5 de la fórmula SI de Excel

Vemos que la función SI realiza la prueba lógica que determina la decisión buscada. Pero, dentro de la función SI está la función Y que criba a los aspirantes que cumplan todas las condiciones pedidas (MBA, experiencia, inglés y titulación). Pero, para resolver la doble posibilidad de o licenciatura en Informática o en Estadística, a su vez, se ha añadido la función O, que detecta si, al menos se dispone de una de las dos.

Cuadro del ejemplo 5 de la fórmula SI de Excel

=SI(Y(C2=»MBA»; D2>=5; E2=»alto»; O(F2=»Estadístico»;F2=»Informático»)); «SI»; «descartado»)


AUTOR: Bernat Requena Serra

AÑO: 2014


SI TE HA GUSTADO, ¡COMPÁRTELO!

También te podría gustar...

787 Respuestas

  1. Efrain dice:

    15% del importe . solo a los productos cuyo precio sea mayor o igual a 750

  2. Antonio dice:

    si en una tabla tengo el total de kilometraje de 25 personas; si el kilometraje es de 0 a 7500 darle un 5%, si es de 7501 a 9000 darle un 10%

  3. PLAY dice:

    IVA: Depende de TOTAL: Si EL TOTAL ES mayor o igual a 202.000; MULTIPLICA EL TOTAL POR
    EL 19%; de lo contrario 0.

  4. Abigail Mambrin dice:

    ayuda por favor
    En este control de ventas se muestra qué productos han sido vendidos o no en los primeros 6 meses. Si aparece 1 significa que fue vendido, caso contrario figura 0.

    En la columna Estado debe mostrarse el código A si fue vendido por 4 meses o más y el código B si fue vendido en menos de 4 meses.

  5. Antonio Matos dice:

    Ayada por favor
    Inserta una fórmula condicional en la celda E8 que te indique los diferentes Estatus de un alumno en un curso. Si el valor en la celda D8 es mayor a 70 entonces la celda E8 debe indicar «APROBADO». Cuando el valor en la celda D8 se encuentre entre 65 y 69, la celda E8 debe indicar «CONVOCATORIA». Y por último, cuando el valor de la celda D8 indique un valor menor a 65, la celda E8 debe indicar «REPROBADO».

    • Respuestas dice:

      Es una fórmula con SI anidada de Excel. En esta página tienes múltiples ejemplos y comentarios resueltos.
      =SI(D8<65;"REPROBADO";SI(D8<70;"CONVOCATORIA";"APROBADO"))
      Como dices que hasta 69 va a "convocatoria", entiendo que "aprobado" empieza con 70, que en tu comentario se ha quedado fuera.
      · ÷

Deja una respuesta

Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *